***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 24, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P4FL3P3A-AU A K 
.param
+vc0 = 2.106e-12	vc1 = 1.856e-9		vc2 = 2.300		vc3 = 2.365e-11		vc4 = 1.081e+1
+tc1 = 2.081e-2		tc2 = 1.511e-2		tc3 = 5.601e-3		tc4 = 4.021e-3
.func irpwr(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v**vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.161e-14	   n = 9.949e-1		  rs = 1.179e-2
+ibv = 10e-3		 nbv = 7.0		  bv = 5.6
+ikf = 8.00e-0
***** capacitance parameter *****
+cjo = 3.636e-9		   m = 2.932e-1		  vj = 5.747e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.062		 xti = 3
+trs1 = -3.025e-3	trs2 = -1.875e-6	tikf = 1.0e-3
+tbv1 = 5.086e-5	tbv2 = -2.228e-7	
.ends P4FL3P3A-AU
*$
